build: W600-SDK importiert, Firmware-Build und Hello am EVK

Docker-Build mit gcc-arm-none-eabi 4.9-2014q4 (statt Homebrew-Cask) verwendet,
Dockerfile/tools/docker.sh dafür aus Task 13 vorgezogen. cmake/sdk.cmake schont
gcc 4.9 (kennt -fcommon/-Wno-error=... nicht). Zwei zusätzliche SDK-Stubs
(EarlyInit, pre_gpio_config) in src/sys/sdk_stubs.c ergänzt, siehe sdk/PATCHES.md.

CMakeLists.txt

@@ -0,0 +1,49 @@
+cmake_minimum_required(VERSION 3.16)
+
+if(EXISTS ${CMAKE_SOURCE_DIR}/config.local.cmake)
+  include(${CMAKE_SOURCE_DIR}/config.local.cmake)
+endif()
+
+project(ninlight C ASM)
+
+if(NOT CMAKE_BUILD_TYPE)
+  set(CMAKE_BUILD_TYPE Release)
+endif()
+
+set(NINLIGHT_DEVICES evk e27_rgb e14_rgb gu10_rgb e27_cw e14_cw gu10_cw g95_cw)
+set(NINLIGHT_DEVICE "" CACHE STRING "Target device")
+if(NOT NINLIGHT_DEVICE IN_LIST NINLIGHT_DEVICES)
+  message(FATAL_ERROR "Set -DNINLIGHT_DEVICE=<one of: ${NINLIGHT_DEVICES}>")
+endif()
+
+if(NOT DEFINED NINLIGHT_TOKEN)
+  set(NINLIGHT_TOKEN "aabbccddeeff0011223344")
+endif()
+
+include(cmake/version.cmake)
+include(cmake/sdk.cmake)
+include(cmake/image.cmake)
+
+set(NL_FW_SOURCES
+  src/app_main.c
+  src/util/nl_sha256.c
+  src/util/nl_crc.c
+  src/sys/fwup_hook_default.c
+  src/sys/sdk_stubs.c)
+
+set(NL_FW ninlight_${NINLIGHT_DEVICE})
+add_executable(${NL_FW} ${NL_SDK_BOOT_SOURCES} ${NL_FW_SOURCES} ${NL_SDK_OBJECTS})
+set_target_properties(${NL_FW} PROPERTIES SUFFIX ".elf")
+target_compile_definitions(${NL_FW} PRIVATE
+  NINLIGHT_DEVICE_ID="${NINLIGHT_DEVICE}"
+  NINLIGHT_FW_VERSION="${NINLIGHT_FW_VERSION}"
+  NINLIGHT_BUILD_DATE="${NINLIGHT_BUILD_DATE}"
+  NINLIGHT_TOKEN_DEFAULT="${NINLIGHT_TOKEN}")
+target_link_options(${NL_FW} PRIVATE
+  -static -nostartfiles -T${SDK_DIR}/ld/link_w600_2m.ld
+  -Wl,-Map=${CMAKE_BINARY_DIR}/${NL_FW}.map)
+target_link_libraries(${NL_FW} PRIVATE
+  -Wl,--whole-archive ${SDK_DIR}/Lib/GNU/libwlan.a -Wl,--no-whole-archive m)
+nl_add_images(${NL_FW})
+
+message(STATUS "ninlight ${NINLIGHT_FW_VERSION} for ${NINLIGHT_DEVICE}")