Michael Sauer
89c764514a
C1: Ein POST an /api/v1/device/state mit tief verschachteltem JSON (z.B. 20 Ebenen "[[[[...") lässt cJSONs rekursiven Parser den 6-KB-Stack des HTTP-Tasks überlaufen - CJSON_NESTING_LIMIT war mit 1000 viel zu hoch und FreeRTOS' Stack-Overflow-Checking ist aus. Begrenzt auf 8 Ebenen, sowohl für die Firmware (third_party/cJSON/cJSON.c) als auch für die Host-Tests (nl_cjson), damit beide dasselbe Verhalten zeigen. Test: test_post_validation deckt jetzt einen Body mit 20 verschachtelten Arrays ab (400 "invalid json").
99 lines
3.0 KiB
CMake
99 lines
3.0 KiB
CMake
cmake_minimum_required(VERSION 3.16)
|
|
|
|
if(EXISTS ${CMAKE_SOURCE_DIR}/config.local.cmake)
|
|
include(${CMAKE_SOURCE_DIR}/config.local.cmake)
|
|
endif()
|
|
|
|
project(ninlight C ASM)
|
|
|
|
if(NOT CMAKE_BUILD_TYPE)
|
|
set(CMAKE_BUILD_TYPE Release)
|
|
endif()
|
|
|
|
set(NINLIGHT_DEVICES evk e27_rgb e14_rgb gu10_rgb e27_cw e14_cw gu10_cw g95_cw)
|
|
set(NINLIGHT_DEVICE "" CACHE STRING "Target device")
|
|
if(NOT NINLIGHT_DEVICE IN_LIST NINLIGHT_DEVICES)
|
|
message(FATAL_ERROR "Set -DNINLIGHT_DEVICE=<one of: ${NINLIGHT_DEVICES}>")
|
|
endif()
|
|
|
|
if(NOT DEFINED NINLIGHT_TOKEN)
|
|
set(NINLIGHT_TOKEN "aabbccddeeff0011223344")
|
|
endif()
|
|
|
|
if(NOT DEFINED NINLIGHT_WIFI_SSID)
|
|
set(NINLIGHT_WIFI_SSID "")
|
|
endif()
|
|
if(NOT DEFINED NINLIGHT_WIFI_PASSWORD)
|
|
set(NINLIGHT_WIFI_PASSWORD "")
|
|
endif()
|
|
if(NOT DEFINED NINLIGHT_AP_PASSWORD)
|
|
set(NINLIGHT_AP_PASSWORD "ninlight")
|
|
endif()
|
|
string(LENGTH "${NINLIGHT_AP_PASSWORD}" _nl_ap_len)
|
|
if(_nl_ap_len LESS 8)
|
|
message(FATAL_ERROR "NINLIGHT_AP_PASSWORD needs at least 8 characters (WPA2)")
|
|
endif()
|
|
foreach(_v NINLIGHT_WIFI_SSID NINLIGHT_WIFI_PASSWORD NINLIGHT_AP_PASSWORD NINLIGHT_TOKEN)
|
|
if("${${_v}}" MATCHES "[\"\\\\]")
|
|
message(FATAL_ERROR "${_v} must not contain \" or \\")
|
|
endif()
|
|
endforeach()
|
|
|
|
include(cmake/version.cmake)
|
|
include(cmake/sdk.cmake)
|
|
include(cmake/image.cmake)
|
|
|
|
set(NL_FW_SOURCES
|
|
src/app_main.c
|
|
src/util/nl_sha256.c
|
|
src/util/nl_crc.c
|
|
src/board/nl_board.c
|
|
src/light/nl_color.c
|
|
src/light/nl_engine.c
|
|
src/light/nl_control.c
|
|
src/light/nl_boot_state.c
|
|
src/config/nl_settings.c
|
|
src/config/nl_state_log.c
|
|
src/config/nl_reset_counter.c
|
|
src/config/nl_flash_w600.c
|
|
src/drivers/nl_led.c
|
|
src/drivers/nl_pwm_leds.c
|
|
src/drivers/nl_sm2135eh.c
|
|
src/sys/nl_console_cmd.c
|
|
src/sys/nl_console.c
|
|
src/sys/fwup_hook_default.c
|
|
src/sys/sdk_stubs.c
|
|
src/net/nl_names.c
|
|
src/net/nl_http.c
|
|
src/net/nl_api.c
|
|
src/net/nl_wifi_sm.c
|
|
src/net/nl_wifi_w600.c
|
|
src/net/nl_mdns.c
|
|
src/net/nl_http_server.c
|
|
src/sys/nl_app_api.c
|
|
third_party/cJSON/cJSON.c)
|
|
|
|
# C1: deeply nested JSON must not overflow the 6 KB HTTP task stack (parse_value recurses).
|
|
set_source_files_properties(third_party/cJSON/cJSON.c PROPERTIES
|
|
COMPILE_DEFINITIONS "CJSON_NESTING_LIMIT=8")
|
|
|
|
set(NL_FW ninlight_${NINLIGHT_DEVICE})
|
|
add_executable(${NL_FW} ${NL_SDK_BOOT_SOURCES} ${NL_FW_SOURCES} ${NL_SDK_OBJECTS})
|
|
set_target_properties(${NL_FW} PROPERTIES SUFFIX ".elf")
|
|
target_compile_definitions(${NL_FW} PRIVATE
|
|
NINLIGHT_DEVICE_ID="${NINLIGHT_DEVICE}"
|
|
NINLIGHT_FW_VERSION="${NINLIGHT_FW_VERSION}"
|
|
NINLIGHT_BUILD_DATE="${NINLIGHT_BUILD_DATE}"
|
|
NINLIGHT_TOKEN_DEFAULT="${NINLIGHT_TOKEN}"
|
|
NINLIGHT_WIFI_SSID="${NINLIGHT_WIFI_SSID}"
|
|
NINLIGHT_WIFI_PASSWORD="${NINLIGHT_WIFI_PASSWORD}"
|
|
NINLIGHT_AP_PASSWORD="${NINLIGHT_AP_PASSWORD}")
|
|
target_link_options(${NL_FW} PRIVATE
|
|
-static -nostartfiles -T${SDK_DIR}/ld/link_w600_2m.ld
|
|
-Wl,-Map=${CMAKE_BINARY_DIR}/${NL_FW}.map)
|
|
target_link_libraries(${NL_FW} PRIVATE
|
|
-Wl,--whole-archive ${SDK_DIR}/Lib/GNU/libwlan.a -Wl,--no-whole-archive m)
|
|
nl_add_images(${NL_FW})
|
|
|
|
message(STATUS "ninlight ${NINLIGHT_FW_VERSION} for ${NINLIGHT_DEVICE}")
|